;********************************************************************
; M64282.ASM [copyright Andy Clark 1999]
; 
; JAVRMOD for Mitsubishi 64823 artificial retina CCD
;
;********************************************************************
;
;********************************************************************
; DEFINE PORT PINS
;********************************************************************

;.include "8515def.inc"

;port definitions
.EQU CM_CONT	= PORTD
.EQU CM_DDR		= DDRD
.EQU AD_DATA	= PINB
.EQU AD_OUT		= PORTB
.EQU AD_DDR		= DDRB
.EQU CM_IN		= TIFR

;signal definitions
.EQU CMSIN		= 2 
.EQU CMLOAD		= 3 
.EQU CMRESET	= 4 
.EQU CMCLK		= 5 
.EQU CMREAD		= 3 
.EQU CMSTART	= 4 

;command definitions
.EQU CMD_RESET	= 1
.EQU CMD_START	= 2

;register definitions
.DEF TEMP		= r20


.CSEG

;********************************************************************
; MACRO DEFINITIONS
; START_BIT : uses the OCR1B output to provide a START pulse
;********************************************************************
.MACRO START_BIT
 ldi	zl,0b00000000	
 out	TCCR1B,zl		;stop timer
 out	TCNT1H,zl		;clear count hi value
 out	TCNT1L,zl		;clear count lo value
 out	OCR1BH,zl		;clear compare hi value
 ldi	zl,1		      
 out	OCR1BL,zl		;set compare lo to 1 CK
 ldi	zl,@0
 out	TCCR1A,zl
 ldi	zl,0b00000001	;start timer
 out	TCCR1B,zl
 ldi	zl,0b00000000	;stop timer
 out	TCCR1B,zl
.ENDMACRO


;********************************************************************
; INITIALISE PORTS
;********************************************************************
_M64282_Init:
	cli            
	ldi	TEMP,0b11111110	;init control port
	out	CM_DDR,TEMP
	ldi	TEMP,0b00010000
	out	CM_CONT,TEMP
	ldi	TEMP,0b11000000	;init adc port (lower 6 bits=input)
	out	AD_DDR,TEMP	
	ldi	TEMP,0b11000000	;turn off pullups
	out	AD_OUT,TEMP
	sei                   
	ret


;********************************************************************
; SendCommand
; decodes and sends a command to camera
; CMD_RESET reset camera
; CMD_START start pulse
;********************************************************************

SendCommand:
_txM64282_C:			;print# @single_command
      cli				;command byte is in TEMP
SC0:	cpi	TEMP,CMD_RESET	;do reset ?
	brne	SC1			
	cbi	CM_CONT,CMRESET	;reset lo
	sbi	CM_CONT,CMCLK	;clk hi
	sbi	CM_CONT,CMRESET	;reset hi
	cbi	CM_CONT,CMCLK	;clk lo
	rjmp	SCX				
SC1:	cpi	TEMP,CMD_START	;do start ?
	brne	SCX			
	cbi	CM_CONT,CMCLK	;clk lo
	START_BIT 0b00110000	;start bit hi macro
	sbi	CM_CONT,CMCLK	;clk hi
	START_BIT 0b00100000	;start bit lo macro
	cbi	CM_CONT,CMCLK	;clk lo
SCX:	sei
	ret


;********************************************************************
; SetRegister 
; serialises addr+data & sends load pulse on last bit
;********************************************************************

SetRegister:
_txM64282_C_cb:			;print# @address,databyte
	cli
	mov	zh,TEMP		;transfer addr to zh
	ldi	TEMP,11		;init bit counter
	cbi	CM_CONT,CMLOAD	;clear load bit
SR0:	cbi	CM_CONT,CMCLK	;clear clk
	cbi	CM_CONT,CMSIN	;clear sin
	sbrc	zh,2			;test bit 2 in upper reg
	sbi	CM_CONT,CMSIN	;set sin
	sbi	CM_CONT,CMCLK	;set clk
	lsl	zl			;zl<1
	rol	zh			;zh<1<zl7
	dec	TEMP			;dec bit count
	brne	SR0			;0?
	sbi	CM_CONT,CMLOAD	;set load
	cbi	CM_CONT,CMCLK	;clear clock
	cbi	CM_CONT,CMLOAD	;clear load
	sei
	ret


;********************************************************************
; GetImage
; read image from camera into a 128*122 buffer
; z points to destination buffer
;********************************************************************

.DEF	LOOPIN	= r16			;inner loop counter
.DEF	LOOPOUT	= r17			;outer loop counter
.DEF	CLK_LO	= r18			;preset clock low register
.DEF	CLK_HI	= r19			;preset clock high register

GetImage:
_rxM64282_sr:			;input# Image
	cli				
					;PRESET VALUES OF CLOCK FOR SPEED
	in	CLK_LO,CM_CONT	;clk low value
	andi	CLK_LO,0b11011111
	in	CLK_HI,CM_CONT	;clk high value
	ori	CLK_HI,0b00100000
					
	ldi	TEMP,0b00000000	;SETUP TIMER1 TO CAPTURE ICP RISING EDGE
	out	TCCR1A,TEMP		;disconnect timer from ocx pins
	ldi	TEMP,0b01000001
	out	TCCR1B,TEMP		;no prescale timer
	in	TEMP,CM_IN		;read tifr register
	ori	TEMP,0b00001000	;CLEAR icp bit (by writing 1)
	out	CM_IN,TEMP		;set tifr register
	
					;LOOP UNTIL CMREAD=1 (NEW FRAME)
GI0:	out	CM_CONT,CLK_LO	;clear clock
	nop				;pad for timing
	out	CM_CONT,CLK_HI	;set clock
	in	TEMP,CM_IN		;read tifr
	sbrs	TEMP,CMREAD		;skip if cmread bit is set (new frame)
	rjmp	GI0			;loop if not

					;DUMMY CLOCK PULSE TO GET VALUE OF FIRST PIXEL		
	out	CM_CONT,CLK_LO	;clear clk
	nop				;pad for timing
	out	CM_CONT,CLK_HI	;set clk

					;MAIN CONVERSION LOOP, 128*122 PIXELS
	ldi	LOOPOUT,61		;outer loop - read 61*256 pixels = 128*122
	clr	LOOPIN		;inner loop - no need to reload as dec wraps to 0
GI1:	out	CM_CONT,CLK_LO	;set clk		
	in	TEMP,PINB		;read ADC
	andi	TEMP,0b00111111	;mask upper 2 bits (6 bit converter)
	ori	TEMP,0b10000000	;**set top bit so we never get a zero value
					;**this is only needed if you want to send the
					;**image out as a string using javrbasic print
	st	z+,TEMP		;store value, increment pointer
GI3:	out	CM_CONT,CLK_HI	;clear clk		
	dec	LOOPIN		;dec inner loop	
	brne	GI1			;test for 0
	dec	LOOPOUT		;dec outer loop
	brne	GI1			;test for 0
					;END OF IMAGE DATA
	ser	TEMP			;set end of frame value
	st	z+,TEMP		
	clr	TEMP			;set end of frame value (again, for JB print)
	st	z,TEMP		
					;DUMMY CONVERSION LOOP, READS INVALID LINES OUT
	ldi	LOOPOUT,3		;outer loop - read 3*256 pixels dummy
	clr	LOOPIN		;inner loop
GI4:	out	CM_CONT,CLK_LO	;set clk		
	nop				;pad for timing, ignore pixel value
	out	CM_CONT,CLK_HI	;clear clk		
	dec	LOOPIN		;dec inner loop	
	brne	GI4			;			
	dec	LOOPOUT		;dec outer loop
	brne	GI4
	
	sei
	ret

	
;copyright Andy Clark 1999
;andyc@zoom.co.uk